#Tietokoneohjelma trendin laskemiseksi
procedure TfrmTreGra.Trend(i1,ii : integer;
                               X : ObsArT;
                         var A,B : real;
                              LE : integer);
{ Calculate LINear or EXPonential trend }
var
 i : integer;
 F,FF,SX,SXT,ST,STT : real;
begin
 IF(ii<i1)  {Onko havaintojen lukumäärä suurempi kuin nolla}
 then begin
  A := 0.0;     {= ...jos viimeisen havainnon numero on }
  B := 0.0;     {pienempi kuin ensimmäisen...}
  Exit;
 end;
  FF := 1.0*(ii-i1+1); {Havaintojen lukumäärä}
  SX      := 0.0;      {Nollataan havaintojen summa}
  SXT     := 0.0;      {Nollataan tulosumma}
  ST      := 0.0;      {Nollataan selittävän summa}
  STT     := 0.0;      {Nollataan selittävän neliösumma}
  
  for i := i1 to ii    {Silmukka ensimmäisestä viimeiseen}
  do begin
   F     := 1.0*i;     {Aikamuuttuja indeksistä}
   ST    := ST + F;    {Kerätään aikamuuttujan summaa}
   STT   := STT + F*F; {Kerätään aikamuuttujan neliösummaa}
   if (LE=1)           {jos lineaarinen trendi,...}
   then begin
    SX  := SX + X[i];  {Kerätään havaintojen summaa}
    SXT := SXT+ X[i]*F;{Kerätään tulosummaa}
   end
   else begin          {jos ei lineaarinen trendi,...}
    IF(X[i]<=0.0) then Exit;  {jos havainto negatiivinen tai nolla, pois}
    SX  := SX + Ln(X[i]);   {Kerätään havaintojen log summaa}
    SXT := SXT + Ln(X[i])*F; {Kerätään tulosummaa}
   end; { else }
  end; { for i }       {Silmukan [loopin] loppu}
  B := (SXT-SX*ST/FF)/(STT-ST*ST/FF);  {Lasketaan kerroin}
  A := SX/FF-B*ST/FF;                  {Lasketaan vakiotermi}
end; { Trend }